diff --git a/WiFi/examples/WifiPachubeClient/WifiPachubeClient.ino b/WiFi/examples/WifiPachubeClient/WifiPachubeClient.ino
new file mode 100644
index 000000000..20cf86bc0
--- /dev/null
+++ b/WiFi/examples/WifiPachubeClient/WifiPachubeClient.ino
@@ -0,0 +1,146 @@
+/*
+  Wifi Pachube sensor client
+ 
+ This sketch connects an analog sensor to Pachube (http://www.pachube.com)
+ using an Arduino Wifi shield.
+ 
+ This example has been updated to use version 2.0 of the Pachube.com API. 
+ To make it work, create a feed with a datastream, and give it the ID
+ sensor1. Or change the code below to match your feed.
+ 
+ Circuit:
+ * Analog sensor attached to analog in 0
+ * Wifi shield attached to pins 10, 11, 12, 13
+ 
+ created 2 March 2012
+ by Tom Igoe
+ 
+ This code is in the public domain.
+ 
+ */
+
+#include <SPI.h>
+#include <WiFi.h>
+
+#define APIKEY         "YOUR API KEY GOES HERE" // replace your pachube api key here
+#define FEEDID         00000 // replace your feed ID
+#define USERAGENT      "My Project" // user agent is the project name
+
+char ssid[] = "yourNetwork";          //  your network SSID (name) 
+char pass[] = "secretPassword";   // your network password
+int status = WL_IDLE_STATUS;
+
+// initialize the library instance:
+WiFiClient client;
+
+long lastConnectionTime = 0;        // last time you connected to the server, in milliseconds
+boolean lastConnected = false;      // state of the connection last time through the main loop
+const int postingInterval = 10000;  //delay between updates to Pachube.com
+
+void setup() {
+  // start serial port:
+  Serial.begin(9600);
+    status = WiFi.begin(ssid, pass);
+  if ( status != WL_CONNECTED) { 
+    Serial.println("Couldn't get a wifi connection");
+    while(true);
+  } 
+  else {
+    Serial.println("Connected to wifi");
+  }
+}
+
+
+void loop() {
+  // read the analog sensor:
+  int sensorReading = analogRead(A0);   
+
+  // if there's incoming data from the net connection.
+  // send it out the serial port.  This is for debugging
+  // purposes only:
+  if (client.available()) {
+    char c = client.read();
+    Serial.print(c);
+  }
+
+  // if there's no net connection, but there was one last time
+  // through the loop, then stop the client:
+  if (!client.connected() && lastConnected) {
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+  }
+
+  // if you're not connected, and ten seconds have passed since
+  // your last connection, then connect again and send data:
+  if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
+    sendData(sensorReading);
+  }
+  // store the state of the connection for next time through
+  // the loop:
+  lastConnected = client.connected();
+}
+
+// this method makes a HTTP connection to the server:
+void sendData(int thisData) {
+  // if there's a successful connection:
+  if (client.connect("www.pachube.com", 80)) {
+    Serial.println("connecting...");
+   // send the HTTP PUT request:
+    client.print("PUT /v2/feeds/");
+    client.print(FEEDID);
+    client.println(".csv HTTP/1.1");
+    client.print("Host: api.pachube.com\n");
+    client.print("X-PachubeApiKey: ");
+    client.println(APIKEY);
+    client.print("User-Agent: ");
+    client.println(USERAGENT);
+    client.print("Content-Length: ");
+
+    // calculate the length of the sensor reading in bytes:
+    // 8 bytes for "sensor1," + number of digits of the data:
+    int thisLength = 8 + getLength(thisData);
+    client.println(thisLength);
+
+    // last pieces of the HTTP PUT request:
+    client.print("Content-Type: text/csv\n");
+    client.println("Connection: close\n");
+
+    // here's the actual content of the PUT request:
+     client.print("sensor1,");
+    client.println(thisData);
+
+    // note the time that the connection was made:
+    lastConnectionTime = millis();
+  } 
+  else {
+  // if you couldn't make a connection:
+    Serial.println("connection failed");
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+    lastConnected = client.connected();
+  }
+}
+
+
+// This method calculates the number of digits in the
+// sensor reading.  Since each digit of the ASCII decimal
+// representation is a byte, the number of digits equals
+// the number of bytes:
+
+int getLength(int someValue) {
+  // there's at least one byte:
+  int digits = 1;
+  // continually divide the value by ten, 
+  // adding one to the digit count for each
+  // time you divide, until you're at 0:
+  int dividend = someValue /10;
+  while (dividend > 0) {
+    dividend = dividend /10;
+    digits++;
+  }
+  // return the number of digits:
+  return digits;
+}
+
diff --git a/WiFi/examples/WifiPachubeClientString/WifiPachubeClientString.ino b/WiFi/examples/WifiPachubeClientString/WifiPachubeClientString.ino
new file mode 100644
index 000000000..0f0697e0b
--- /dev/null
+++ b/WiFi/examples/WifiPachubeClientString/WifiPachubeClientString.ino
@@ -0,0 +1,127 @@
+/*
+  Wifi Pachube sensor client with Strings
+ 
+ This sketch connects an analog sensor to Pachube (http://www.pachube.com)
+ using a Arduino Wifi shield.
+ 
+ This example uses the String library, which is part of the Arduino core from
+ version 0019.  
+ 
+ Circuit:
+ * Analog sensor attached to analog in 0
+ * Wifi shield attached to pins 10, 11, 12, 13
+ 
+ created 2 March 2012
+ by Tom Igoe
+ 
+ This code is in the public domain.
+ 
+ */
+
+#include <SPI.h>
+#include <WiFi.h>
+
+#define APIKEY         "YOUR API KEY GOES HERE" // replace your pachube api key here
+#define FEEDID         00000 // replace your feed ID
+#define USERAGENT      "My Project" // user agent is the project name
+
+char ssid[] = "yourNetwork";          //  your network SSID (name) 
+char pass[] = "secretPassword";   // your network password
+int status = WL_IDLE_STATUS;
+
+// initialize the library instance:
+WiFiClient client;
+
+long lastConnectionTime = 0;        // last time you connected to the server, in milliseconds
+boolean lastConnected = false;      // state of the connection last time through the main loop
+const int postingInterval = 10000;  //delay between updates to Pachube.com
+
+void setup() {
+  // start serial port:
+  Serial.begin(9600);
+    status = WiFi.begin(ssid, pass);
+  if ( status != WL_CONNECTED) { 
+    Serial.println("Couldn't get a wifi connection");
+    while(true);
+  } 
+  else {
+    Serial.println("Connected to wifi");
+  }
+}
+
+void loop() {
+  // read the analog sensor:
+  int sensorReading = analogRead(A0);   
+  // convert the data to a String to send it:
+  
+  String dataString = "sensor1,";
+ dataString += sensorReading;
+
+  // you can append multiple readings to this String if your
+  // pachube feed is set up to handle multiple values:
+  int otherSensorReading = analogRead(A1);
+  dataString += "\nsensor2,";
+  dataString += otherSensorReading;
+
+  // if there's incoming data from the net connection.
+  // send it out the serial port.  This is for debugging
+  // purposes only:
+  if (client.available()) {
+    char c = client.read();
+    Serial.print(c);
+  }
+
+  // if there's no net connection, but there was one last time
+  // through the loop, then stop the client:
+  if (!client.connected() && lastConnected) {
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+  }
+
+  // if you're not connected, and ten seconds have passed since
+  // your last connection, then connect again and send data:
+  if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
+    sendData(dataString);
+  }
+  // store the state of the connection for next time through
+  // the loop:
+  lastConnected = client.connected();
+}
+
+// this method makes a HTTP connection to the server:
+void sendData(String thisData) {
+  // if there's a successful connection:
+  if (client.connect("api.pachube.com", 80)) {
+    Serial.println("connecting...");
+    // send the HTTP PUT request:
+    client.print("PUT /v2/feeds/");
+    client.print(FEEDID);
+    client.println(".csv HTTP/1.1");
+    client.print("Host: api.pachube.com\n");
+    client.print("X-PachubeApiKey: ");
+    client.println(APIKEY);
+    client.print("User-Agent: ");
+    client.println(USERAGENT);
+    client.print("Content-Length: ");
+    client.println(thisData.length(), DEC);
+
+    // last pieces of the HTTP PUT request:
+    client.print("Content-Type: text/csv\n");
+    client.println("Connection: close\n");
+
+    // here's the actual content of the PUT request:
+    client.println(thisData);
+
+    // note the time that the connection was made:
+    lastConnectionTime = millis();
+  } 
+  else {
+    // if you couldn't make a connection:
+    Serial.println("connection failed");
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+    lastConnected = client.connected();
+  }
+}