Added Pachube client to Ethernet Library examples

libraries/Ethernet/examples/PachubeClient/PachubeClient.pde

@@ -0,0 +1,139 @@
+/*
+  Pachube sensor client
+ 
+ This sketch connects an analog sensor to Pachube (http://www.pachube.com)
+ using a Wiznet Ethernet shield. You can use the Arduino Ethernet shield, or
+ the Adafruit Ethernet shield, either one will work, as long as it's got
+ a Wiznet Ethernet module on board.
+ 
+ Circuit:
+ * Analog sensor attached to analog in 0
+ * Ethernet shield attached to pins 10, 11, 12, 13
+ 
+ created 15 March 2010
+ updated 25 July 2010
+ by Tom Igoe
+ 
+ http://www.tigoe.net/pcomp/code/category/arduinowiring/873
+ This code is in the public domain.
+ 
+ */
+
+// include the Ethernet library
+#include <Ethernet.h>
+
+// assign a MAC address for the ethernet controller.
+// fill in your address here:
+byte mac[] = { 
+  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};
+// assign an IP address for the controller:
+byte ip[] = { 
+  192,169,1,20 };
+byte gateway[] = {
+  192,168,1,1};	
+byte subnet[] = { 
+  255, 255, 255, 0 };
+
+//  The address of the server you want to connect to (pachube.com):
+byte server[] = { 
+  209,40,205,190 }; 
+
+// initialize the library instance:
+Client client(server, 80);
+
+long lastConnectionTime = 0;        // last time you connected to the server, in milliseconds
+boolean lastConnected = false;      // state of the connection last time through the main loop
+const int postingInterval = 10000;  //delay between updates to Pachube.com
+
+void setup() {
+  // start the ethernet connection and serial port:
+  Ethernet.begin(mac, ip);
+  Serial.begin(9600);
+  // give the ethernet module time to boot up:
+  delay(1000);
+}
+
+void loop() {
+  // read the analog sensor:
+  int sensorReading = analogRead(0);   
+
+  // if there's incoming data from the net connection.
+  // send it out the serial port.  This is for debugging
+  // purposes only:
+  if (client.available()) {
+    char c = client.read();
+    Serial.print(c);
+  }
+
+  // if there's no net connection, but there was one last time
+  // through the loop, then stop the client:
+  if (!client.connected() && lastConnected) {
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+  }
+
+  // if you're not connected, and ten seconds have passed since
+  // your last connection, then connect again and send data:
+  if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
+    sendData(sensorReading);
+  }
+  // store the state of the connection for next time through
+  // the loop:
+  lastConnected = client.connected();
+}
+
+// this method makes a HTTP connection to the server:
+void sendData(int thisData) {
+  // if there's a successful connection:
+  if (client.connect()) {
+    Serial.println("connecting...");
+    // send the HTTP PUT request. 
+    // fill in your feed address here:
+    client.print("PUT /api/YOUR_FEED_HERE.csv HTTP/1.1\n");
+    client.print("Host: www.pachube.com\n");
+    // fill in your Pachube API key here:
+    client.print("X-PachubeApiKey: YOUR_KEY_HERE\n");
+    client.print("Content-Length: ");
+
+    // calculate the length of the sensor reading in bytes:
+    int thisLength = getLength(thisData);
+    client.println(thisLength, DEC);
+
+    // last pieces of the HTTP PUT request:
+    client.print("Content-Type: text/csv\n");
+    client.println("Connection: close\n");
+
+    // here's the actual content of the PUT request:
+    client.println(thisData, DEC);
+
+    // note the time that the connection was made:
+    lastConnectionTime = millis();
+  } 
+  else {
+    // if you couldn't make a connection:
+    Serial.println("connection failed");
+  }
+}
+
+
+// This method calculates the number of digits in the
+// sensor reading.  Since each digit of the ASCII decimal
+// representation is a byte, the number of digits equals
+// the number of bytes:
+
+int getLength(int someValue) {
+  // there's at least one byte:
+  int digits = 1;
+  // continually divide the value by ten, 
+  // adding one to the digit count for each
+  // time you divide, until you're at 0:
+  int dividend = someValue /10;
+  while (dividend > 0) {
+    dividend = dividend /10;
+    digits++;
+  }
+  // return the number of digits:
+  return digits;
+}
+